Manage ThingsBoard with Terraform

# This is the Terraform setting, that is required when you are using a 3rd party terraform provider (i.e. magodo/restful).
# See: https://www.terraform.io/language/settings#specifying-a-required-terraform-version.
terraform {
  required_providers {
    restful = {
      source = "magodo/restful"
      version = "= 0.2.0"
    }
  }
}

# Following are user defined variable, which are input as parameter when you run Terraform

# `base_url` is the URL of the thingsbaord-api-proxy (see: https://github.com/magodo/thingsboard-api-proxy), e.g. http://localhost:12345/api
variable "base_url" {
  type = string
}

# `username` is the username used when login in from ThingsBoard UI
variable "username" {
  type    = string
  default = "tenant@thingsboard.org"
}

# `password` is the password used when login in from ThingsBoard UI
variable "password" {
  type    = string
  default = "tenant"
}

# This is the provider config for the magodo/restful provider.
# See: https://www.terraform.io/language/providers/configuration for a general description of this block.
# See: https://registry.terraform.io/providers/magodo/restful/latest/docs for the meaning of each attribute.
provider "restful" {
  base_url = var.base_url
  security = {
    oauth2 = {
      token_url = format("%s/auth/login", var.base_url)
      username  = var.username
      password  = var.password
    }
  }
}

# This is a Data Source for querying user information.
# See: https://www.terraform.io/language/data-sources for a introduction of Data Source.
# See: https://registry.terraform.io/providers/magodo/restful/latest/docs/data-sources/restful_resource for the meaning of each attribute.
data "restful_resource" "user" {
  id = "/users"
  query = {
    pageSize = [10]
    page     = [0]
  }
  selector = format("data.#(name==%s)", var.username)
}

# This is a Resource for managing a ThingsBoard customer.
# See: https://www.terraform.io/language/resources for a introduction of  Resource.
# See: https://registry.terraform.io/providers/magodo/restful/latest/docs/resources/restful_resource for the meaning of each attribute.
# Note that this resource implicitly depends on the data source `restful_resource.user` for the tenant Id.
resource "restful_resource" "customer" {
  path      = "/customer"
  name_path = "id.id"
  body = jsonencode({
    title = "Example Company"
    tenantId = {
      id         = jsondecode(data.restful_resource.user.output).tenantId.id
      entityType = "TENANT"
    }
    country  = "US"
    state    = "NY"
    city     = "New York"
    address  = "addr1"
    address2 = "addr2"
    zip      = "10004"
    phone    = "+1(415)777-7777"
    email    = "example@company.com"
  })
}

# This is a Resource for managing a ThingsBoard device profile.
# Note that this resource implicitly depends on the data source `restful_resource.user` for the tenant Id.
resource "restful_resource" "device_profile" {
  path      = "/deviceProfile"
  name_path = "id.id"
  body = jsonencode({
    tenantId = {
      id         = jsondecode(data.restful_resource.user.output).tenantId.id
      entityType = "TENANT"
    }
    name               = "My Profile"
    description        = "Example device profile"
    type               = "DEFAULT"
    transportType      = "DEFAULT"
    defaultRuleChainId = null
    defaultDashboardId = null
    defaultQueueName   = null
    profileData = {
      configuration = {
        type = "DEFAULT"
      }
      transportConfiguration = {
        type = "DEFAULT"
      }
      provisionConfiguration = {
        type                  = "DISABLED"
        provisionDeviceSecret = null
      }
      alarms = null
    }
    provisionDeviceKey = null
    firmwareId         = null
    softwareId         = null
    default            = false
  })
}

# This is a Resource for managing a ThingsBoard device.
# Note that this resource implicitly depends on the data source `restful_resource.user`, resource `restful_resource.customer` and `restful_device_profile`.
resource "restful_resource" "device" {
  path      = "/device"
  name_path = "id.id"
  body = jsonencode({
    tenantId = {
      id         = jsondecode(data.restful_resource.user.output).tenantId.id
      entityType = "TENANT"
    }
    customerId = {
      id         = jsondecode(restful_resource.customer.output).id.id
      entityType = "CUSTOMER"
    }
    name  = "My Device"
    label = "Room 123 Sensor"
    deviceProfileId : {
      id         = jsondecode(restful_resource.device_profile.output).id.id
      entityType = "DEVICE_PROFILE"
    }
  })
}

# This is a Data Source for retrieving the device credential of the resource created via `restful_resource.device` .
data "restful_resource" "device_credential" {
  id = format("%s/credentials", restful_resource.device.id)
}

# These two resources are used to generate the UUID of a device entity (entity alias for the single device created above) and a device widget (which is created below).
resource "random_uuid" "my_device_entity" {}
resource "random_uuid" "my_device_widget" {}

# User defined local variables.
# See: https://www.terraform.io/language/values/locals. 
locals {
  # A local variable holds the definition of the device entity, which is actually a single entity maps the device we created above.
  # Note that it implicitly depends on the `restful_resource.device` and `random_uuid.my_device_entity`.
  my_device_entity = {
    alias = "MyDevice"
    filter = {
      resolveMultiple = false
      singleEntity = {
        entityType = "DEVICE"
        id         = jsondecode(restful_resource.device.output).id.id
      }
      type = "singleEntity"
    }
    id = random_uuid.my_device_entity.id
  }

  # A local variable holds the definition of a device widget, which is actually a "Card" widget.
  # Note that it implicitly depends on the `local.my_device_entity` and `random_uuid.my_device_widget`.
  my_device_widget = {
    bundleAlias = "cards"
    col         = 0
    config = {
      actions         = {}
      backgroundColor = "#ff5722"
      color           = "rgba(255, 255, 255, 0.87)"
      datasources = [
        {
          dataKeys = [
            {
              _hash    = 0.009193323503694284
              color    = "#2196f3"
              label    = "temperature"
              name     = "temperature"
              settings = {}
              type     = "timeseries"
            },
          ]
          entityAliasId = local.my_device_entity.id
          filterId      = null
          name          = null
          type          = "entity"
        },
      ]
      decimals         = 0
      dropShadow       = true
      enableFullscreen = true
      padding          = "16px"
      settings = {
        labelPosition = "top"
      }
      showLegend = false
      showTitle  = false
      timewindow = {
        realtime = {
          timewindowMs = 60000
        }
      }
      title = "New Simple card"
      titleStyle = {
        fontSize   = "16px"
        fontWeight = 400
      }
      units                  = "°C"
      useDashboardTimewindow = true
      widgetStyle            = {}
    }
    description  = null
    id           = random_uuid.my_device_widget.id
    image        = null
    isSystemType = true
    row          = 0
    sizeX        = 5
    sizeY        = 3
    title        = "New widget"
    type         = "latest"
    typeAlias    = "simple_card"
  }
}

# This is a Resource for managing a ThingsBoard dashboard.
# Note that this resource implicitly depends on a couple of resources/local variables we defined above.
resource "restful_resource" "dashboard" {
  path      = "/dashboard"
  name_path = "id.id"
  body = jsonencode({
    tenantId = {
      id         = jsondecode(data.restful_resource.user.output).tenantId.id
      entityType = "TENANT"
    }
    title = "My Dashboard"
    configuration = {
      entityAliases = {
        (local.my_device_entity.id) = local.my_device_entity
      }
      filters = {}
      settings = {
        showDashboardExport     = true
        showDashboardTimewindow = true
        showDashboardsSelect    = true
        showEntitiesSelect      = true
        showTitle               = false
        stateControllerId       = "entity"
        toolbarAlwaysOpen       = true
      }
      states = {
        default = {
          layouts = {
            main = {
              gridSettings = {
                backgroundColor    = "#eeeeee"
                backgroundSizeMode = "100%"
                columns            = 24
                margin             = 10
              }
              widgets = {
                (local.my_device_widget.id) = {
                  col   = 0
                  row   = 0
                  sizeX = 5
                  sizeY = 3
                }
              }
            }
          }
          name = "My Dashboard"
          root = true
        }
      }
      widgets = {
        (local.my_device_widget.id) = local.my_device_widget
      }
    }
  })
}

# A Terraform output variable, that output the device credential that is retrieved via the Data Source `restful_resource.device_credential`.
# See: https://www.terraform.io/language/values/outputs
output "device_token" {
  value     = jsondecode(data.restful_resource.device_credential.output).credentialsId
  sensitive = true
}